自动以管理员身份运行bat文件

seeker908

1. @echo off
   
2. title 获取管理员权限
   
3. mode con cols=100 lines=20
   
4. color 3f
   
5. 
   
6. :: 开始获取管理员权限
   
7. setlocal
   
8. set uac=~uac_permission_tmp_%random%
   
9. md "%SystemRoot%\system32\%uac%" 2>nul
   
10. if %errorlevel%==0 ( rd "%SystemRoot%\system32\%uac%" >nul 2>nul ) else (
    
11.     echo set uac = CreateObject^("Shell.Application"^)>"%temp%\%uac%.vbs"
    
12.     echo uac.ShellExecute "%~s0","","","runas",1 >>"%temp%\%uac%.vbs"
    
13.     echo WScript.Quit >>"%temp%\%uac%.vbs"
    
14.     "%temp%\%uac%.vbs" /f
    
15.     del /f /q "%temp%\%uac%.vbs" & exit )
    
16. endlocal
    
17. :: 完成获取,下面可以开始写你自己的代码了
    
18. 
    
19. echo.
    
20. echo 原理：先尝试在系统目录下临时新建一个文件夹，若已获取管理员权限或是运行在XP等不需要管理员权限的
    
21. echo       老系统时，是可以新建成功的，此时只需删除这个临时新建的文件夹就好了，否则通过创建一个临时
    
22. echo       vbs脚本获取管理员权限，然后再删除这个临时vbs脚本文件。
    
23. echo.
    
24. echo 提示：当获取管理员目录后，你的批处理运行目录会发生变化，为保证目录准确，
    
25. echo       可通过 cd 切换目录,例“cd /d %%~dp0”切换回批处理所在目录
    
26. echo.
    
27. echo 当前运行目录： %cd%\
    
28. echo 批处理所在目录：%~dp0
    
29. echo.
    
30. echo 例：切换回批处理所在目录
    
31. echo cd /d %%~dp0
    
32. echo.
    
33. 
    
34. cd /d %~dp0
    
35. 
    
36. echo 当前运行目录： %cd%\
    
37. echo 批处理所在目录：%~dp0       
    
38. 
    
39. pause
    
40. exit

复制代码

seeker908

一句话代码-无临时文件

1. @echo off&(cd/d "%~dp0")&(cacls "%SystemDrive%\System Volume Information" >nul 2>&1)||(start "" mshta vbscript:CreateObject^("Shell.Application"^).ShellExecute^("%~snx0"," %*","","runas",1^)^(window.close^)&exit /b)

复制代码

seeker908

仅判断，提示用户自行操作

1. @echo off&(cd/d "%~dp0")&(cacls "%SystemDrive%\System Volume Information" >nul 2>&1)||(color 4f&echo 请右键“以管理员身份运行”&echo.&pause&exit /b)

复制代码